Chapter Contents

Previous

Next

Example 65.5: Preference Mapping of Cars Data

This example uses PROC TRANSREG to perform a preference mapping (PREFMAP) analysis (Carroll 1972) of car preference data after a PROC PRINQUAL principal component analysis. The PREFMAP analysis is a response surface regression that locates ideal points for each dependent variable in a space defined by the independent variables.

The data are ratings obtained from 25 judges of their preference for each of 17 automobiles. The ratings were made on a zero (very weak preference) to nine (very strong preference) scale. These judgments were made in 1980 about that year's products. There are two character variables that indicate the manufacturer and model of the automobile. The data set also contains three ratings: miles per gallon (MPG), projected reliability (Reliability), and quality of the ride (Ride). These ratings are on a one (bad) to five (good) scale. PROC PRINQUAL creates an OUT= data set containing standardized principal component scores (Prin1 and Prin2), along with the ID variables MODEL, MPG, Reliability, and Ride.

The first PROC TRANSREG step fits univariate regression models for MPG and Reliability. All variables are designated IDENTITY. A vector drawn in the plot of Prin1 and Prin2 from the origin to the point defined by an attribute's regression coefficients approximately shows how the cars differ on that attribute. Refer to Carroll (1972) for more information. The Prin1 and Prin2 columns of the TResult1 OUT= data set contain the car coordinates (_Type_='SCORE' observations) and endpoints of the MPG and Reliability vectors (_Type_='M COEFFI' observations).

The second PROC TRANSREG step fits a univariate regression model with Ride designated IDENTIY, and Prin1 and Prin2 designated POINT. The POINT expansion creates an additional independent variable _ISSQ_, which contains the sum of Prin1 squared and Prin2 squared. The OUT= data set TResult2 contains no _Type_='SCORE' observations, only ideal point (_Type_='M POINT') coordinates for Ride. The coordinates of both the vectors and the ideal points are output by specifying COORDINATES in the OUTPUT statement in PROC TRANSREG.

A vector model is used for MPG and Reliability because perfectly efficient and reliable cars do not exist in the data set. The ideal points for MPG and Reliability are far removed from the plot of the cars. It is more likely that an ideal point for quality of the ride is in the plot, so an ideal point model is used for the ride variable. Refer to Carroll (1972) and Schiffman, Reynolds, and Young (1981) for discussions of the vector model and point models (including the EPOINT and QPOINT versions of the point model that are not used in this example).

The final DATA step combines the two output data sets and creates a data set suitable for the %PLOTIT macro. (For information on the %PLOTIT macro, see Appendix B, "Using the %PLOTIT Macro.") The plot contains one point per car and one point for each of the three ratings. The %PLOTIT macro options specify the input data set, how to handle anti-ideal points (described later), and where to draw horizontal and vertical reference lines. The DATATYPE= option specifies that the input data set contains results of a PREFMAP vector model and a PREFMAP ideal point model. This instructs the macro to draw vectors to _Type_='M COEFFI' observations and circles around _Type_='M POINT' observations.

An unreliable to reliable direction extends from the left and slightly below the origin to the right and slightly above the origin. The Japanese and European Cars are rated, on the average, as more reliable. A low MPG to good MPG direction extends from the top left of the plot to the bottom right. The smaller cars, on the average, get better gas mileage. The ideal point for Ride is in the top, just right of the center of the plot. Cars near the Ride ideal point tend to have a better ride than cars far away. It can be seen from the iteration history tables that none of these ratings perfectly fits the model, so all of the interpretations are approximate.

The Ride point is a "negative-negative" ideal point. The point models assume that small ratings mean the object (car) is similar to the rating name and large ratings imply dissimilarity to the rating name. Because the opposite scoring is used, the interpretation of the Ride point must be reversed to a negative ideal point (bad ride). However, the coefficient for the _ISSQ_ variable is negative, so the interpretation is reversed again, back to the original interpretation. Anti-ideal points are taken care of in the %PLOTIT macro. Specify ANTIIDEA=1 when large values are positive or ideal and ANTIIDEA=-1 when small values are positive or ideal.

The following statements produce Output 65.5.1 through Output 65.5.2:

   title 'Preference Ratings for Automobiles Manufactured in 1980';

   data CarPreferences;
      input Make $ 1-10 Model $ 12-22 @25 (Judge1-Judge25) (1.)
            MPG Reliability Ride;
      datalines;
   Cadillac   Eldorado     8007990491240508971093809 3 2 4
   Chevrolet  Chevette     0051200423451043003515698 5 3 2
   Chevrolet  Citation     4053305814161643544747795 4 1 5
   Chevrolet  Malibu       6027400723121345545668658 3 3 4
   Ford       Fairmont     2024006715021443530648655 3 3 4
   Ford       Mustang      5007197705021101850657555 3 2 2
   Ford       Pinto        0021000303030201500514078 4 1 1
   Honda      Accord       5956897609699952998975078 5 5 3
   Honda      Civic        4836709507488852567765075 5 5 3
   Lincoln    Continental  7008990592230409962091909 2 4 5
   Plymouth   Gran Fury    7006000434101107333458708 2 1 5
   Plymouth   Horizon      3005005635461302444675655 4 3 3
   Plymouth   Volare       4005003614021602754476555 2 1 3
   Pontiac    Firebird     0107895613201206958265907 1 1 5
   Volkswagen Dasher       4858696508877795377895000 5 3 4
   Volkswagen Rabbit       4858509709695795487885000 5 4 3
   Volvo      DL           9989998909999987989919000 4 5 5
   ;

   *---Compute Coordinates for a 2-Dimensional Scatter Plot of Cars---;
   proc prinqual data=CarPreferences out=PResults(drop=Judge1-Judge25)
                 n=2 replace standard scores;
      id Model MPG Reliability Ride;
      transform identity(Judge1-Judge25);
      title2 'Multidimensional Preference (MDPREF) Analysis';
   run;

   *---Compute Endpoints for MPG and Reliability Vectors---;
   proc transreg data=PResults;
      Model identity(MPG Reliability)=identity(Prin1 Prin2);
      output tstandard=center coordinates replace out=TResult1;
      id Model;
      title2 'Preference Mapping (PREFMAP) Analysis';
   run;

   *---Compute Ride Ideal Point Coordinates---;
   proc transreg data=PResults;
      Model identity(Ride)=point(Prin1 Prin2);
      output tstandard=center coordinates replace noscores out=TResult2;
      id Model;
   run;

   proc print; run;

   *---Combine Data Sets and Plot the Results---;
   data plot;
      title3 'Plot of Automobiles and Ratings';
      set Tresult1 Tresult2;
   run;

   %plotit(data=plot, datatype=vector ideal, antiidea=1, HREF=0, vref=0);

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.