Chapter Contents

Previous

Next

Example 22.9: Repeated Measures, Two Repeated Measurement Factors

   title 'Diagnostic Procedure Comparison';
   data a;
      input std1 $ test1 $ std2 $ test2 $ wt @@;
      datalines;
   neg neg neg neg 509  neg neg neg pos  4  neg neg pos neg  17
   neg neg pos pos   3  neg pos neg neg 13  neg pos neg pos   8
   neg pos pos pos   8  pos neg neg neg 14  pos neg neg pos   1
   pos neg pos neg  17  pos neg pos pos  9  pos pos neg neg   7
   pos pos neg pos   4  pos pos pos neg  9  pos pos pos pos 170
   ;

For the initial model, the response functions are marginal probabilities, and the repeated measurement factors are Time and Treatment. The model is a saturated one, containing effects for Time, Treatment, and Time*Treatment. The following statements produce Output 22.9.1 through Output 22.9.5:

   proc catmod data=a;
      title2 'Marginal Symmetry, Saturated Model';
      weight wt;
      response marginals;
      model std1*test1*std2*test2=_response_ / freq noparm;
      repeated Time 2, Treatment 2 / _response_=Time Treatment 
               Time*Treatment;
   run;

The analysis of variance table in Output 22.9.5 shows that there is no significant effect of Time, either by itself or in its interaction with Treatment. Thus, the second model includes only the Treatment effect. Again, the response functions are marginal probabilities, and the repeated measurement factors are Time and Treatment. A main effect model with respect to Treatment is fit. The following statements produce Output 22.9.6 through Output 22.9.9:

      title2 'Marginal Symmetry, Reduced Model';
      model std1*test1*std2*test2=_response_ / noprofile corrb;
      repeated Time 2, Treatment 2 / _response_=Treatment;
   run;

The next example illustrates a RESPONSE statement that, at each time, computes the sensitivity and specificity of the test diagnostic procedure with respect to the standard procedure. Since these are measures of the relative accuracy of the two diagnostic procedures, the repeated measurement factors in this case are labeled Time and Accuracy. Only fifteen of the sixteen possible responses are observed, so additional care must be taken in formulating the RESPONSE statement for computation of sensitivity and specificity.

The following statements produce Output 22.9.11 through Output 22.9.15:

      title2 'Sensitivity and Specificity Analysis, ' 
             'Main-Effects Model';
      model std1*test1*std2*test2=_response_ / covb noprofile;
      repeated Time 2, Accuracy 2 / _response_=Time Accuracy;
      response exp  1 -1  0  0  0  0  0  0,
                    0  0  1 -1  0  0  0  0,
                    0  0  0  0  1 -1  0  0,
                    0  0  0  0  0  0  1 -1

                log 0 0 0 0   0 0 0   0 0 0 0   1 1 1 1,
                    0 0 0 0   0 0 0   1 1 1 1   1 1 1 1,
                    1 1 1 1   0 0 0   0 0 0 0   0 0 0 0,
                    1 1 1 1   1 1 1   0 0 0 0   0 0 0 0,
                    0 0 0 1   0 0 1   0 0 0 1   0 0 0 1,
                    0 0 1 1   0 0 1   0 0 1 1   0 0 1 1,
                    1 0 0 0   1 0 0   1 0 0 0   1 0 0 0,
                    1 1 0 0   1 1 0   1 1 0 0   1 1 0 0;
   quit;

1. sensitivity, time 1
2. specificity, time 1
3. sensitivity, time 2
4. specificity, time 2

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.