Example 22.8: Repeated Measures, Logistic Analysis of Growth Curve
The data, from a longitudinal study reported in Koch et
al. (1977), are from patients in four populations (2
diagnostic groups × 2 treatments) who are measured
at three times to assess their response (n=normal or
a=abnormal) to treatment.
title 'Growth Curve Analysis';
data growth2;
input Diagnosis $ Treatment $ week1 $ week2 $ week4 $ count @@;
datalines;
mild std n n n 16 severe std n n n 2
mild std n n a 13 severe std n n a 2
mild std n a n 9 severe std n a n 8
mild std n a a 3 severe std n a a 9
mild std a n n 14 severe std a n n 9
mild std a n a 4 severe std a n a 15
mild std a a n 15 severe std a a n 27
mild std a a a 6 severe std a a a 28
mild new n n n 31 severe new n n n 7
mild new n n a 0 severe new n n a 2
mild new n a n 6 severe new n a n 5
mild new n a a 0 severe new n a a 2
mild new a n n 22 severe new a n n 31
mild new a n a 2 severe new a n a 5
mild new a a n 9 severe new a a n 32
mild new a a a 0 severe new a a a 6
;
The analysis is directed at assessing the effect of the
repeated measurement factor, Time, as well as the
independent variables, Diagnosis (mild or severe) and
Treatment (std or new). The RESPONSE statement is used
to compute the logits of the marginal probabilities. The
times used in the design matrix (0, 1, 2) correspond to the
logarithms (base 2) of the actual times (1, 2, 4). The
following statements produce Output 22.8.1 through
Output 22.8.7:
proc catmod order=data data=growth2;
title2 'Reduced Logistic Model';
weight count;
population Diagnosis Treatment;
response logit;
model week1*week2*week4=(1 0 0 0, /* mild, std */
1 0 1 0,
1 0 2 0,
1 0 0 0, /* mild, new */
1 0 0 1,
1 0 0 2,
0 1 0 0, /* severe, std */
0 1 1 0,
0 1 2 0,
0 1 0 0, /* severe, new */
0 1 0 1,
0 1 0 2)
(1='Mild diagnosis, week 1',
2='Severe diagnosis, week 1',
3='Time effect for std trt',
4='Time effect for new trt')
/ freq;
contrast 'Diagnosis effect, week 1' all_parms 1 -1 0 0;
contrast 'Equal time effects' all_parms 0 0 1 -1;
quit;
Output 22.8.1: Logistic Analysis of Growth Curve
Growth Curve Analysis |
Reduced Logistic Model |
Response |
week1*week2*week4 |
Response Levels |
8 |
Weight Variable |
count |
Populations |
4 |
Data Set |
GROWTH2 |
Total Frequency |
340 |
Frequency Missing |
0 |
Observations |
29 |
|
Output 22.8.2: Population Profiles
Growth Curve Analysis |
Reduced Logistic Model |
Population Profiles |
Sample |
Diagnosis |
Treatment |
Sample Size |
1 |
mild |
std |
80 |
2 |
mild |
new |
70 |
3 |
severe |
std |
100 |
4 |
severe |
new |
90 |
Response Profiles |
Response |
week1 |
week2 |
week4 |
1 |
n |
n |
n |
2 |
n |
n |
a |
3 |
n |
a |
n |
4 |
n |
a |
a |
5 |
a |
n |
n |
6 |
a |
n |
a |
7 |
a |
a |
n |
8 |
a |
a |
a |
|
The samples and the response
numbers are defined in Output 22.8.2.
Output 22.8.3: Response Frequencies
Growth Curve Analysis |
Reduced Logistic Model |
Response Frequencies |
Sample |
Response Number |
1 |
2 |
3 |
4 |
5 |
6 |
7 |
8 |
1 |
16 |
13 |
9 |
3 |
14 |
4 |
15 |
6 |
2 |
31 |
0 |
6 |
0 |
22 |
2 |
9 |
0 |
3 |
2 |
2 |
8 |
9 |
9 |
15 |
27 |
28 |
4 |
7 |
2 |
5 |
2 |
31 |
5 |
32 |
6 |
|
Output 22.8.4: Design Matrix
Growth Curve Analysis |
Reduced Logistic Model |
Sample |
Function Number |
Response Function |
Design Matrix |
1 |
2 |
3 |
4 |
1 |
1 |
0.05001 |
1 |
0 |
0 |
0 |
|
2 |
0.35364 |
1 |
0 |
1 |
0 |
|
3 |
0.73089 |
1 |
0 |
2 |
0 |
2 |
1 |
0.11441 |
1 |
0 |
0 |
0 |
|
2 |
1.29928 |
1 |
0 |
0 |
1 |
|
3 |
3.52636 |
1 |
0 |
0 |
2 |
3 |
1 |
-1.32493 |
0 |
1 |
0 |
0 |
|
2 |
-0.94446 |
0 |
1 |
1 |
0 |
|
3 |
-0.16034 |
0 |
1 |
2 |
0 |
4 |
1 |
-1.53148 |
0 |
1 |
0 |
0 |
|
2 |
0.00000 |
0 |
1 |
0 |
1 |
|
3 |
1.60944 |
0 |
1 |
0 |
2 |
|
Output 22.8.5: Analysis of Variance
Growth Curve Analysis |
Reduced Logistic Model |
Analysis of Variance |
Source |
DF |
Chi-Square |
Pr > ChiSq |
Mild diagnosis, week 1 |
1 |
0.28 |
0.5955 |
Severe diagnosis, week 1 |
1 |
100.48 |
<.0001 |
Time effect for std trt |
1 |
26.35 |
<.0001 |
Time effect for new trt |
1 |
125.09 |
<.0001 |
Residual |
8 |
4.20 |
0.8387 |
|
The analysis of variance table (Output 22.8.5) shows that
the data can be adequately modeled by two parameters that
represent diagnosis effects at week 1 and two log-linear
time effects (one for each treatment). Both of the time
effects are significant.
Output 22.8.6: Parameter Estimates
Growth Curve Analysis |
Reduced Logistic Model |
Analysis of Weighted Least Squares Estimates |
Effect |
Parameter |
Estimate |
Standard Error |
Chi- Square |
Pr > ChiSq |
Model |
1 |
-0.0716 |
0.1348 |
0.28 |
0.5955 |
|
2 |
-1.3529 |
0.1350 |
100.48 |
<.0001 |
|
3 |
0.4944 |
0.0963 |
26.35 |
<.0001 |
|
4 |
1.4552 |
0.1301 |
125.09 |
<.0001 |
|
Output 22.8.7: Contrasts
Growth Curve Analysis |
Reduced Logistic Model |
Analysis of Contrasts |
Contrast |
DF |
Chi-Square |
Pr > ChiSq |
Diagnosis effect, week 1 |
1 |
77.02 |
<.0001 |
Equal time effects |
1 |
59.12 |
<.0001 |
|
The analysis of contrasts (Output 22.8.7) shows that the
diagnosis effect at week 1 is highly significant. In
Output 22.8.6, since the estimate of the logit for the
severe diagnosis effect (parameter 2) is more negative than
it is for the mild diagnosis effect (parameter 1), there is
a smaller predicted probability of the first response
(normal) for the severe diagnosis group. In other words,
those subjects with a severe diagnosis have a significantly
higher probability of abnormal response at week 1 than those
subjects with a mild diagnosis.
The analysis of contrasts also shows that the time effect
for the standard treatment is significantly different than
the one for the new treatment. The table of parameter
estimates (Output 22.8.6) shows that the time effect for the
new treatment (parameter 4) is stronger than it is for the
standard treatment (parameter 3).
Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.