Example 4.12: Using the COMBINE option

The GANTT Procedure

Example 4.12: Using the COMBINE option

When you monitor a project in progress, as in the previous example, it is evident that there are no actual dates beyond TIMENOW and that PROC CPM sets the early times to the corresponding actual times for activities that are completed or in progress (see Output 4.11.1). For example, activities 1 through 4 have their early schedule equal to the actual schedule. Activities 5 and 6 have their early start equal to the actual start; however the actual finish for these two activities is missing since they are in progress at TIMENOW. Finally, activities 7 through 14 have no actual information.

The COMBINE option in PROC GANTT exploits the fact that the early times are made consistent with the actual times to strip away a lot of the redundancy and produce a more compact Gantt chart while retaining all of the essential schedule information. Specifying the COMBINE option in the CHART statement of the previous example produces the Gantt chart in Output 4.12.1. Instead of using two separate bars to draw the early/late schedule and the actual schedule, the COMBINE option causes PROC GANTT to use one bar to represent all three schedules and draws a timenow line. The actual schedule is shown to the left of TIMENOW and the early/late schedule is shown to the right of TIMENOW. Thus for activities 1 through 4, the actual schedule is drawn on the first bar to the left of the timenow line. Activities 5 and 6 are in progress at TIMENOW, which is indicated by the actual start positioned to the left of TIMENOW and the predicted early/late schedule, based on the progress made up to TIMENOW, drawn to the right of TIMENOW. Activities 7 through 14 have not yet started, and this is reflected in their predicted early/late schedules drawn to the right of TIMENOW.

The COMBINE option draws a timenow line by default, and if the TIMENOW= option is not specified, the procedure computes the value of TIMENOW based on the schedule data as explained in the "Syntax" section. In this example, specifying the COMBINE option without the TIMENOW= option causes a timenow line to be drawn on December 19, 1991, since this is the first day following the largest actual value. The CTNOW= option is used to specify the color of the timenow line. You can change the line style and line width of the timenow line by specifying the LTNOW= and WTNOW= options, respectively, in the CHART statement.

   title f=swiss 'Gantt Example 12';
   title2 f=swiss 'Using the COMBINE Option';

   * set vpos to 50 and hpos to 100;

   goptions vpos=50 hpos=100;


   * set up required pattern statements;

   pattern1 c=green v=s;  /* duration of a noncrit. activity  */
   pattern2 c=green v=e;  /* slack time for a noncrit. act.   */
   pattern3 c=red   v=s;  /* duration of a critical activity  */
   pattern4 c=red   v=e;  /* slack time for a supercrit. act. */
   pattern5 c=red   v=r2; /* duration of a supercrit. act.    */
   pattern6 c=cyan  v=s;  /* actual duration of an activity   */
   pattern7 c=black v=x1; /* break due to a holiday           */
   pattern8 c=cyan  v=x2; /* res. constrained dur of an act.  */
   pattern9 c=blue  v=s;  /* baseline duration of an activity */


   * plot the combined and baseline schedules using proc gantt;

   proc gantt graphics data=widgupdt holidata=holidays;
      chart / holiday=(holiday) holifin=(holifin)
              timenow='20dec91'd ctnow=red
              combine
              dur=days
              font=swiss
              compress;
      id task;
   run;

Output 4.12.1: Using the COMBINE Option in Graphics Mode

Chapter Contents
Previous
Next
Top