Well-Separated Clusters

Introduction to Clustering Procedures

Well-Separated Clusters

If the population clusters are sufficiently well separated, almost any clustering method performs well, as demonstrated in the following example using single linkage. In this and subsequent examples, the output from the clustering procedures is not shown, but cluster membership is displayed in scatter plots. The following SAS statements produce Figure 8.1:

   data compact;
      keep x y;
      n=50; scale=1;
      mx=0; my=0; link generate;
      mx=8; my=0; link generate;
      mx=4; my=8; link generate;
      stop;
   generate:
      do i=1 to n;
         x=rannor(1)*scale+mx;
         y=rannor(1)*scale+my;
         output;
      end;
      return;
   run;

   proc cluster data=compact outtree=tree 
                method=single noprint;
   run;

   proc tree noprint out=out n=3;
      copy x y;
   run;

   legend1 frame cframe=ligr  cborder=black
           position=center value=(justify=center);
   axis1 minor=none label=(angle=90 rotate=0);
   axis2 minor=none;
   proc gplot; 
      plot y*x=cluster/frame cframe=ligr
           vaxis=axis1 haxis=axis2 legend=legend1;
      title 'Single Linkage Cluster Analysis';
      title2 'of Data Containing Well-Separated, 
              Compact Clusters';
   run;

Figure 8.1: Data Containing Well-Separated, Compact Clusters: PROC CLUSTER with METHOD=SINGLE and PROC GPLOT

Chapter Contents
Previous
Next
Top