Example 57.3: Custom Scoring Coefficients

The SCORE Procedure

Example 57.3: Custom Scoring Coefficients

This example uses a specially created custom scoring data set and produces Output 57.3.1. The first scoring coefficient creates a variable that is Age-Weight; the second scoring coefficient evaluates the variable RunPulse-RstPulse; and the third scoring coefficient totals all six variables. Since the scoring coefficients data set (data set A) does not contain any observations with _TYPE_='MEAN' or _TYPE_='STD', the data in the Fitness data set (see Example 57.1) are not standardized before scoring.

   data A;
      input _type_ $ _name_ $
            Age Weight RunTime RunPulse RestPulse;
      datalines;
   SCORE  AGE_WGT  1 -1  0  0  0
   SCORE  RUN_RST  0  0  0  1 -1
   SCORE  TOTAL    1  1  1  1  1
   ;

   proc print data=A;
      title 'CONSTRUCTED SCORING EXAMPLE';
      title2 'Scoring Coefficients';
   run;

   proc score data=Fitness score=A out=B;
      var Age Weight RunTime RunPulse RestPulse;
   run;

   proc print data=B;
      title2 'Scored Data';
   run;

Output 57.3.1: Custom Scoring Data Set and Scored Fitness Data: PROC PRINT

CONSTRUCTED SCORING EXAMPLE

Scoring Coefficients

Obs	_type_	_name_	Age	Weight	RunTime	RunPulse	RestPulse
1	SCORE	AGE_WGT	1	-1	0	0	0
2	SCORE	RUN_RST	0	0	0	1	-1
3	SCORE	TOTAL	1	1	1	1	1

Output 57.3.2: Custom Scored Fitness Data: PROC PRINT

CONSTRUCTED SCORING EXAMPLE

Scored Data

Obs	Age	Weight	Oxygen	RunTime	RestPulse	RunPulse	AGE_WGT	RUN_RST	TOTAL
1	44	89.47	44.609	11.37	62	178	-45.47	116	384.84
2	40	75.07	45.313	10.07	62	185	-35.07	123	372.14
3	44	85.84	54.297	8.65	45	156	-41.84	111	339.49
4	42	68.15	59.571	8.17	40	166	-26.15	126	324.32
5	38	89.02	49.874	9.22	55	178	-51.02	123	369.24
6	47	77.45	44.811	11.63	58	176	-30.45	118	370.08
7	40	75.98	45.681	11.95	70	176	-35.98	106	373.93
8	43	81.19	49.091	10.85	64	162	-38.19	98	361.04
9	44	81.42	39.442	13.08	63	174	-37.42	111	375.50
10	38	81.87	60.055	8.63	48	170	-43.87	122	346.50
11	44	73.03	50.541	10.13	45	168	-29.03	123	340.16
12	45	87.66	37.388	14.03	56	186	-42.66	130	388.69

Chapter Contents
Previous
Next
Top