Chapter Contents

Previous

Next

Example 54.3: Logistic Regression

In this example, a series of people are questioned as to whether or not they would subscribe to a new newspaper. For each person, the variables sex (Female, Male), age, and subs (1=yes,0=no) are recorded. The PROBIT procedure is used to fit a logistic regression model to the probability of a positive response (subscribing) as a function of the variables sex and age. Specifically, the probability of subscribing is modeled as

p = Pr( subs = 1) = F ( b₀ + b₁ × sex + b₂ × age )

By default, the PROBIT procedure models the probability of the lower response level for binary data. One way to model Pr( subs = 1) is to format the response variable so that the formatted value corresponding to subs = 1 is the lower level. The following statements format the values of subs as 1 = 'accept' and 0 = 'reject', so that PROBIT models Pr(accept) = Pr( subs = 1).

The following statements produce Output 54.3.1:

   data news;
      input sex $ age subs;
      datalines;
   Female     35    0
   Male       44    0
   Male       45    1
   Female     47    1
   Female     51    0
   Female     47    0
   Male       54    1
   Male       47    1
   Female     35    0
   Female     34    0
   Female     48    0
   Female     56    1
   Male       46    1
   Female     59    1
   Female     46    1
   Male       59    1
   Male       38    1
   Female     39    0
   Male       49    1
   Male       42    1
   Male       50    1
   Female     45    0
   Female     47    0
   Female     30    1
   Female     39    0
   Female     51    0
   Female     45    0
   Female     43    1
   Male       39    1
   Male       31    0
   Female     39    0
   Male       34    0
   Female     52    1
   Female     46    0
   Male       58    1
   Female     50    1
   Female     32    0
   Female     52    1
   Female     35    0
   Female     51    0
   ;

   proc format;
      value subscrib 1 = 'accept' 0 = 'reject';
   run;

   proc probit;
      class subs sex;
      model subs=sex age / d=logistic itprint;
      format subs subscrib.;
      title 'Logistic Regression of Subscription Status';
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.