Chapter Contents

Previous

Next

Example 54.1: Dosage Levels

In this example, Dose is the variable representing the level of the stimulus, N represents the number of subjects tested at each level of the stimulus, and Response is the number of subjects responding to that level of the stimulus. Both probit and logit response models are fit to the data. The LOG10 option in the PROC statement requests that the log base 10 of Dose is used as the independent variable. Specifically, for a given level of Dose, the probability p of a positive response is modeled as

p = Pr( Response) = F ( b₀ + b₁ ×log₁₀( Dose) )

The probabilities are estimated first using the normal distribution function and then using the logistic distribution function. Note that, in this model specification, the natural rate is assumed to be zero.

Lack-of-fit tests and inverse confidence limits are also requested.

In the DATA step that reads the data, a number of observations are generated that have a missing value for the response. Although the PROBIT procedure does not use the observations with the missing values to fit the model, it does give predicted values for all nonmissing sets of independent variables. These data points fill in the plot of fitted and observed values in the logistic model. The plot displays the estimated logistic cumulative distribution function and the observed response rates.

The following statements produce Output 54.1.1:

   data a;
      infile cards eof=eof;
      input Dose N Response;
      Observed= Response/N;
      output;
      return;
   eof: do Dose=0.5 to 7.5 by 0.25;
           output;
        end;
      datalines;
   1 10 1
   2 12 2
   3 10 4
   4 10 5
   5 12 8
   6 10 8
   7 10 10
   ;

   proc probit log10;
      model Response/N=Dose / lackfit inversecl itprint;
      model Response/N=Dose / d=logistic inversecl;
      output out=B p=Prob std=std xbeta=xbeta;
      title 'Output from Probit Procedure';
   run;
   
   legend1 label=none frame cframe=ligr cborder=black
      position=center value=(justify=center);
   axis1 minor=none color=black label=(angle=90 rotate=0) ;
   axis2 minor=none color=black;
   proc gplot;
      plot Observed*Dose Prob*Dose / overlay frame cframe=ligr
         vaxis=axis1 haxis=axis2 legend=legend1;
      title 'Plot of Observed and Fitted Probabilities';
   run;

The p-values in the Goodness-of-Fit table of 0.6009 for the Pearson chi-square and 0.4616 for the likelihood ratio chi-square indicate an adequate fit for the model fit with the normal distribution.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.