Chapter Contents

Previous

Next

Example 30.6: Multivariate Analysis of Variance

For each of 26 samples of pottery, the percentages of oxides of five metals are measured. The following statements create the data set and invoke the GLM procedure to perform a one-way MANOVA. Additionally, it is of interest to know whether the pottery from one site in Wales (Llanederyn) differs from the samples from other sites; a CONTRAST statement is used to test this hypothesis.

   data pottery;
      title1 "Romano-British Pottery";
      input Site $12. Al Fe Mg Ca Na;
      datalines;
   Llanederyn   14.4 7.00 4.30 0.15 0.51
   Llanederyn   13.8 7.08 3.43 0.12 0.17
   Llanederyn   14.6 7.09 3.88 0.13 0.20
   Llanederyn   11.5 6.37 5.64 0.16 0.14
   Llanederyn   13.8 7.06 5.34 0.20 0.20
   Llanederyn   10.9 6.26 3.47 0.17 0.22
   Llanederyn   10.1 4.26 4.26 0.20 0.18
   Llanederyn   11.6 5.78 5.91 0.18 0.16
   Llanederyn   11.1 5.49 4.52 0.29 0.30
   Llanederyn   13.4 6.92 7.23 0.28 0.20
   Llanederyn   12.4 6.13 5.69 0.22 0.54
   Llanederyn   13.1 6.64 5.51 0.31 0.24
   Llanederyn   12.7 6.69 4.45 0.20 0.22
   Llanederyn   12.5 6.44 3.94 0.22 0.23
   Caldicot     11.8 5.44 3.94 0.30 0.04
   Caldicot     11.6 5.39 3.77 0.29 0.06
   IslandThorns 18.3 1.28 0.67 0.03 0.03
   IslandThorns 15.8 2.39 0.63 0.01 0.04
   IslandThorns 18.0 1.50 0.67 0.01 0.06
   IslandThorns 18.0 1.88 0.68 0.01 0.04
   IslandThorns 20.8 1.51 0.72 0.07 0.10
   AshleyRails  17.7 1.12 0.56 0.06 0.06
   AshleyRails  18.3 1.14 0.67 0.06 0.05
   AshleyRails  16.7 0.92 0.53 0.01 0.05
   AshleyRails  14.8 2.74 0.67 0.03 0.05
   AshleyRails  19.1 1.64 0.60 0.10 0.03
   ;
   proc glm data=pottery;
      class Site;
      model Al Fe Mg Ca Na = Site;
      contrast 'Llanederyn vs. the rest' Site 1 1 1 -3;
      manova h=_all_ / printe printh;
   run;

After the summary information, displayed in Output 30.6.1, PROC GLM produces the univariate analyses for each of the dependent variables, as shown in Output 30.6.2. These analyses show that sites are significantly different for all oxides individually. You can suppress these univariate analyses by specifying the NOUNI option in the MODEL statement.

The PRINTE option also displays the partial correlation matrix associated with the E matrix. In this example, none of the oxides are very strongly correlated; the strongest correlation (r=0.488) is between magnesium oxide and calcium oxide.

Four multivariate tests are computed, all based on the characteristic roots and vectors of E^-1H. These roots and vectors are displayed along with the tests. All four tests can be transformed to variates that have F distributions under the null hypothesis. Note that the four tests all give the same results for the contrast, since it has only one degree of freedom. In this case, the multivariate analysis matches the univariate results: there is an overall difference between the chemical composition of samples from different sites, and the samples from Llanederyn are different from the average of the other sites.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.