Example 19.6: Longitudinal Factor Analysis

The CALIS Procedure

Example 19.6: Longitudinal Factor Analysis

The following example (McDonald 1980) illustrates both the ability of PROC CALIS to formulate complex covariance structure analysis problems by the generalized COSAN matrix model and the use of program statements to impose nonlinear constraints on the parameters. The example is a longitudinal factor analysis using the Swaminathan (1974) model. For m = 3 tests, k = 3 occasions, and r = 2 factors the matrix model is formulated in the section "First-Order Autoregressive Longitudinal Factor Model" as follows:

C = F₁F₂F₃LF₃^-1F₂^-1P(F₂^-1)'(F₃^-1)'L'F₃'F₂'F₁' + U²

$F_1 = \pmatrix{B_1& & \cr &B_2& \cr & &B_3\cr} , F_2 = \pmatrix{I_2& & \cr &D_2& \cr & &D_2\cr} , F_3 = \pmatrix{I_2& &\cr &I_2& \cr & &D_3\cr}$

$L = \pmatrix{I_2&o&o\cr I_2&I_2&o\cr I_2&I_2&I_2\cr} , P = \pmatrix{I_2& &\c... ...atrix{U_{11}&U_{12}&U_{13}\cr U_{21}&U_{22}&U_{23}\cr U_{31}&U_{32}&U_{33}\cr}$

S₂ = I₂ - D₂² , S₃ = I₂ - D₃²

The Swaminathan longitudinal factor model assumes that the factor scores for each (m) common factor change from occasion to occasion (k) according to a first-order autoregressive scheme. The matrix F₁ contains the k factor loading matrices B₁, B₂, B₃ (each is n ×m). The matrices D₂, D₃, S₂, S₃ and U_ij, i,j = 1, ... ,k, are diagonal, and the matrices D_i and S_i, i = 2, ... ,k, are subjected to the constraint

S_i + D_i² = I

Since the constructed correlation matrix given in McDonald's (1980) paper is singular, only unweighted least-squares estimates can be computed.

   data Mcdon(TYPE=CORR);                                                     
   Title "Swaminathan's Longitudinal Factor Model, Data: McDONALD(1980)";     
   Title2 "Constructed Singular Correlation Matrix, GLS & ML not possible";   
      _TYPE_ = 'CORR'; INPUT _NAME_ $ Obs1-Obs9;                              
      datalines;                                                              
   Obs1  1.000    .      .      .      .      .      .      .      .          
   Obs2   .100  1.000    .      .      .      .      .      .      .          
   Obs3   .250   .400  1.000    .      .      .      .      .      .          
   Obs4   .720   .108   .270  1.000    .      .      .      .      .          
   Obs5   .135   .740   .380   .180  1.000    .      .      .      .          
   Obs6   .270   .318   .800   .360   .530  1.000    .      .      .          
   Obs7   .650   .054   .135   .730   .090   .180  1.000    .      .          
   Obs8   .108   .690   .196   .144   .700   .269   .200  1.000    .          
   Obs9   .189   .202   .710   .252   .336   .760   .350   .580  1.000        
     ;                                                                        
                                                                              
   proc calis data=Mcdon method=ls tech=nr nobs=100;                          
   cosan B(6,Gen) * D1(6,Dia) * D2(6,Dia) * T(6,Low) * D3(6,Dia,Inv) *        
                    D4(6,Dia,Inv) * P(6,Dia) + U(9,Sym);                      
      Matrix B                                                                  
               [ ,1]= X1-X3,                                                  
               [ ,2]= 0. X4-X5,                                               
               [ ,3]= 3 * 0. X6-X8,                                           
               [ ,4]= 4 * 0. X9-X10,                                          
               [ ,5]= 6 * 0. X11-X13,                                         
               [ ,6]= 7 * 0. X14-X15;                                         
      Matrix D1                                                                 
               [1,1]= 2 * 1. X16 X17 X16 X17;                                 
      Matrix D2                                                                 
               [1,1]= 4 * 1. X18 X19;                                         
      Matrix T                                                                  
               [1,1]= 6 * 1.,                                                 
               [3,1]= 4 * 1.,                                                 
               [5,1]= 2 * 1.;                                                 
      Matrix D3                                                                 
               [1,1]= 4 * 1. X18 X19;                                         
      Matrix D4                                                                 
               [1,1]= 2 * 1. X16 X17 X16 X17;                                 
      Matrix P                                                                  
               [1,1]= 2 * 1. X20-X23;                                         
      Matrix U                                                                  
               [1,1]= X24-X32,                                                
               [4,1]= X33-X38,                                                
               [7,1]= X39-X41;                                                
      Bounds 0. <= X24-X32,                                                     
            -1. <= X16-X19 <= 1.;                                               
      X20 = 1. - X16 * X16;                                                     
      X21 = 1. - X17 * X17;                                                     
      X22 = 1. - X18 * X18;                                                     
      X23 = 1. - X19 * X19;                                                     
   run;

Because this formulation of Swaminathan's model in general leads to an unidentified problem, the results given here are different from those reported by McDonald (1980). The displayed output of PROC CALIS also indicates that the fitted central model matrices P and U are not positive definite. The BOUNDS statement constrains the diagonals of the matrices P and U to be nonnegative, but this cannot prevent U from having three negative eigenvalues. The fact that many of the published results for more complex models in covariance structure analysis are connected to unidentified problems implies that more theoretical work should be done to study the general features of such models.

Chapter Contents
Previous
Next
Top