Reading Preestablished Control Limits

MCHART Statement

Reading Preestablished Control Limits

See SHWMCHR in the SAS/QC Sample Library

In the previous example, the OUTLIMITS= data set DETLIM saved control limits computed from the measurements in DETERGNT. This example shows how these limits can be applied to new data provided in the following data set:

   data detergt2;
      input lot @;
      do i=1 to 5;
         input weight @;
         output;
         end;
      drop i;
      datalines;
   29 16.66 27.49 18.87 22.53 24.72
   30 23.74 23.67 23.64 20.26 22.09
   31 24.56 24.82 23.92 26.67 21.38
   32 25.89 28.73 29.21 25.38 23.47
   33 23.32 21.61 30.75 23.13 23.82
   34 23.04 22.65 24.96 19.64 26.84
   35 24.01 24.38 24.86 26.50 24.37
   36 26.43 27.36 28.74 26.74 26.27
   37 21.41 22.24 25.34 20.59 27.51
   38 22.62 20.81 22.64 30.15 25.32
   39 26.86 28.14 24.06 27.35 22.49
   40 23.03 23.83 25.59 19.85 22.33
   41 23.19 23.63 23.00 21.46 27.57
   42 27.38 23.18 24.99 24.81 28.82
   43 26.60 26.58 20.26 26.27 24.96
   44 26.22 23.28 24.15 24.06 28.23
   45 25.90 22.88 25.55 24.50 19.95
   46 16.66 27.49 18.87 22.53 24.72
   47 23.74 23.67 23.64 20.26 22.09
   48 24.56 24.82 23.92 26.67 21.38
   49 25.89 28.73 29.21 25.38 23.47
   50 23.32 21.61 30.75 23.13 23.82
   ;

The following statements create a median chart for the data in DETERGT2 using the control limits in DETLIM:

   title 'Median Chart for Weights';
    symbol v=dot c=yellow;
   proc shewhart data=detergt2 limits=detlim;
      mchart weight*lot / cframe   = viv
                          cinfill  = vpav
                          cconnect = yellow;
   run;

The chart is shown in Figure 35.9. The LIMITS= option in the PROC SHEWHART statement specifies the data set containing the control limits. By default,^* this information is read from the first observation in the LIMITS= data set for which

the value of _VAR_ matches the process name WEIGHT
the value of _SUBGRP_ matches the subgroup-variable name LOT

Figure 35.9: Median Chart for Second Set of Detergent Box Weight Data

The chart indicates that the process is in control, since all the medians lie within the control limits.

In this example, the LIMITS= data set was created in a previous run of the SHEWHART procedure. You can also create a LIMITS= data set with the DATA step. See "LIMITS= Data Set" for details concerning the variables that you must provide.

Chapter Contents
Previous
Next
Top