Creating Individual Measurements and Moving Range Charts

IRCHART Statement

Creating Individual Measurements and Moving Range Charts

See SHWIR1 in the SAS/QC Sample Library

An aeronautics company manufacturing jet engines measures the inner diameter of the forward face of each engine (in centimeters). The following statements create a SAS data set that contains the diameter measurements for 20 engines:

   data jets;
      input engine diam @@;
      label engine = "Engine Number";
   datalines;
    1 78.4   2 80.1   3 84.4   4 79.1   5 80.4
    6 83.5   7 73.8   8 83.5   9 75.0  10 76.8
   11 70.5  12 80.3  13 82.4  14 79.4  15 86.4
   16 90.5  17 77.7  18 82.5  19 79.9  20 83.2
   ;

A listing of JETS is shown in Figure 34.1.

The Data Set JETS

engine	diam
1	78.4
2	80.1
3	84.4
4	79.1
5	80.4
6	83.5
7	73.8
8	83.5
9	75.0
10	76.8
11	70.5
12	80.3
13	82.4
14	79.4
15	86.4
16	90.5
17	77.7
18	82.5
19	79.9
20	83.2

Figure 34.1: Listing of the Data Set JETS

Each observation contains the diameter measurement and identification number for a particular engine. The variable ENGINE identifies the sequence of engines and is referred to as the subgroup-variable.^* The variable DIAM contains the measurements and is referred to as the process variable (or process for short).

Since the production rate is low, individual measurements and moving range charts are used to monitor the process. The following statements create the charts shown in Figure 34.2:

   title 'Individual Measurements and Moving Range Charts';
   title2 'Jet Engine Diameters (cm)';
   symbol v=dot c=yellow;
   proc shewhart data=jets;
      irchart diam*engine / cframe   = vigb
                            cconnect = yellow
                            cinfill  = vlib;
   run;

This example illustrates the basic form of the IRCHART statement. After the keyword IRCHART, you specify the process to analyze (in this case, DIAM), followed by an asterisk and the subgroup-variable (ENGINE).

The input data set is specified with the DATA= option in the PROC SHEWHART statement.

Figure 34.2: Individual Measurements and Moving Range Charts

Each point on the individual measurements chart indicates the inner diameter of a particular engine. Each point on the moving range chart indicates the range of the two most recent measurements. For instance, the moving range plotted for the second engine is |78.4 - 80.1| = 1.7. No moving range is plotted for the first engine. Since all of the individual measurements and moving ranges lie within the control limits, it can be concluded that the process is in statistical control.

By default, the control limits shown are $3\sigma$ limits estimated from the data; the formulas for the limits are given . You can also read control limits from an input data set; see "Reading Preestablished Control Limits" .

Chapter Contents
Previous
Next
Top