Example 32.5: Creating Box-and-Whisker Plots with Different Line Styles and Colors

BOXCHART Statement

Example 32.5: Creating Box-and-Whisker Plots with Different Line Styles and Colors

See SHWBOX7 in the SAS/QC Sample Library

The control limits in Output 32.4.1 apply to the subgroup means. This example illustrates how you can modify the chart to indicate whether the variability of the process is in control. The following statements create a box chart for DELAY in which a dashed outline and a light gray fill color are used for a box-and-whisker plot if the corresponding subgroup standard deviation exceeds its $3\sigma$ limits.

First, the SHEWHART procedure is used to create an OUTTABLE= data set (DELAYTAB) that contains a variable (_EXLIMS_) that records which standard deviations exceed their $3\sigma$ limits.

   proc shewhart data=times2;
      xschart delay * day / nochart
                            outtable = delaytab;
   run;

Then, this information is used to set the line styles and fill colors as follows:

   data delaytab;
      length boxcol $ 8;
      set delaytab;
      keep day lnstyle boxcol;
      if _exlims_ = 'UPPER' or _exlims_ = 'LOWER' then do;
         lnstyle  = 2;
         boxcol   = 'ligr';
         end;
      else do;
         lnstyle  = 1;
         boxcol   = 'dagr';
         end;

   data times2;
      merge times2 delaytab;
      by day;
   run;

The following statements create the modified box chart:

   title  'Analysis of Airline Departure Delays' ;
   title2 '--- Standard Deviation Out of Control';
   symbol v=plus c=bib;

   proc shewhart data=times2;
      boxchart delay * day /
         stddeviations
         nohlabel
         boxstyle      = schematic
         llimits       = 1
         cboxfill      = ( boxcol )
         lboxes        = ( lnstyle )
         boxwidthscale = 1 
         cframe        = vligb
         cinfill       = ligr
         cboxes        = dagr
         idcolor       = salmon;
   run;

The chart is shown in Output 32.5.1. The values of the variable LNSTYLE specified with the LBOXES= option determine the outline styles for the box-and-whisker plots. The values of the variable BOXCOL specified with the CBOXFILL= option determines the fill colors. For further details, see the entries for these options in Chapter 46, "Dictionary of Options." The chart indicates that the large variability for March 2 should be checked.

Output 32.5.1: Box Chart Displaying Out-of-Control Subgroup Standard Deviations

Chapter Contents
Previous
Next
Top