Creating a Pareto Chart Using Frequency Data

VBAR Statement

Creating a Pareto Chart Using Frequency Data

See PARETO5 in the SAS/QC Sample Library

In some situations, a count (frequency) is available for each category, or you can compress a large data set by creating a frequency variable for the categories before applying the PARETO procedure.

For example, you can use the FREQ procedure to obtain the compressed data set FAILURE2 from the data set FAILURE1.

   proc freq data=failure1;
      tables cause / noprint out=failure2;

   proc print;
   run;

A listing of FAILURE2 is shown in Figure 26.3.

Obs	cause	COUNT	PERCENT
1	Contamination	14	45.1613
2	Corrosion	2	6.4516
3	Doping	1	3.2258
4	Metallization	2	6.4516
5	Miscellaneous	3	9.6774
6	Oxide Defect	8	25.8065
7	Silicon Defect	1	3.2258

Figure 26.3: The Data Set FAILURE2 Created Using PROC FREQ

The following statements produce a Pareto chart for the data in FAILURE2:

   title 'Analysis of IC Failures';
   symbol color = salmon h = .8;;
   proc pareto data=failure2;
      vbar cause / freq       = count
                   scale      = count
                   interbar   = 1.0
                   last       = 'Miscellaneous'
                   nlegend    = 'Total Circuits'
                   cframenleg = ywh
                   cframe     = ligr
                   cbars      = vigb
                   cconnect   = salmon;
   run;

The chart is displayed in Figure 26.4.

Figure 26.4: Pareto Chart with Frequency Scale

A slash (/) is used to separate the process variable CAUSE from the options specified in the VBAR statement. The frequency variable COUNT is specified with the FREQ= option. Specifying the keyword COUNT with the SCALE= option requests a frequency scale for the vertical axis.

The INTERBAR= option inserts a small space between the bars, and specifying LAST='Miscellaneous' causes the category Miscellaneous to be displayed last regardless of its frequency. The NLEGEND= option adds a sample size legend labeled Total Circuits, and the CFRAMENLEG= option frames the legend. The SYMBOL statement marks points on the curve with dots. In the preceding statements, adding the keyword LINEPRINTER to the PROC PARETO statement requests a line printer version of the chart, which is displayed in Figure 26.5. ^*

Analysis of IC Failures

        ---------------------------------------------------------------         
    35 +---------------------                                          |        
       ||Total Circuits = 31|                                          |        
       |---------------------                                          |        
       |                                                             +*+ 100    
    30 +                                                          +++  |        
       |                                                       +++     |     C  
       |                                        ++++*++++++++*+        |     u  
       |                                 ++*++++                       |     m  
    25 +                             ++++                              + 80  u  
       |                      ++++*++                                  |     l  
       |                 *++++                                         |     a  
       |                +                                              |     t  
  C 20 +              ++                                               |     i  
  o    |             +                                                 + 60  v  
  u    |            +                                                  |     e  
  n    |          ++                                                   |        
  t 15 +         +                                                     |     P  
       |--------*                                                      |     e  
       ||       |                                                      + 40  r  
       ||       |                                                      |     c  
    10 +|       |                                                      |     e  
       ||       |                                                      |     n  
       ||       |---------                                             |     t  
       ||       ||       |                                             + 20     
     5 +|       ||       |                                             |        
       ||       ||       |                                             |        
       ||       ||       |------------------                  ---------|        
       ||       ||       ||       ||       |------------------|       ||        
     0 +|       ||       ||       ||       ||       ||       ||       |+ 0      
        ----+--------+--------+--------+--------+--------+--------+----         
            1        2        3        4        5        6        7             
                                                                                
                               Cause of Failure                                 
                                                                                
  Categories:    1 Contamination    2 Oxide Defect     3 Corrosion              
                 4 Metallization    5 Doping           6 Silicon Defect         
                 7 Miscellaneous

Figure 26.5: Pareto Chart for IC Failures in the Data Set FAILURE2

There are two sets of tied categories in this example; Corrosion and Metallization each occur twice, and Doping and Silicon Defect each occur once. The procedure displays tied categories in alphabetical order of their formatted values. Thus, Corrosion appears before Metallization, and Doping appears before Silicon Defect in Figure 26.4 and Figure 26.5. This is simply a convention, and no practical significance should be attached to the order in which tied categories are arranged.

Chapter Contents
Previous
Next
Top