Example 10.4: Estimating Cpk from a Normal Q-Q Plot

QQPLOT Statement

Example 10.4: Estimating Cpk from a Normal Q-Q Plot

See CAPQQ1 in the SAS/QC Sample Library

This example illustrates how you can use a normal Q-Q plot to estimate the capability index C_pk. The data used here are the distance measurements provided in the "Creating a Normal Quantile-Quantile Plot" section. The linearity of the point pattern in Figure 10.3 indicates that the measurements are normally distributed (recall that normality should be checked when process capability indices are reported). Furthermore, Figure 10.3 shows that the upper specification limit is about 1.7 standard deviation units above the mean, and the lower specification limit is about 1.8 standard deviation units below the mean. Since CPU is defined as

${CPU} = \frac{USL - \mu}{3\sigma}$

and CPL is defined as

${CPL} = \frac{\mu - LSL}{3\sigma}$

it follows that an estimate of CPU is 1.7 / 3 = 0.57, and an estimate of CPL is 1.8 / 3 = 0.6. Thus, except for a factor of three, you can estimate CPU and CPL from the points of intersection between the specification lines and the point pattern.

The following statements facilitate this type of estimation by creating a Q-Q plot, displayed in Output 10.4.1, in which the horizontal axis is rescaled by a factor of three:

   title "Normal Quantile-Quantile Plot for Hole Distance";
   proc capability data=sheets noprint;
      spec  lsl=9.5   llsl=2   clsl=blue
            usl=10.5  lusl=20  cusl=blue;
      qqplot distance / normal(mu=est sigma=est color=yellow w=2
                           cpkscale cpkref)
                        nolegend
                        square
                        cframe = ligr;
      inset n mean (5.2) std="Std Dev" (4.2) cpk (4.2) /
            pos=(-0.75,10.48) data refpoint=tl cfill=blank;
   run;

The CPKSCALE option rescales the horizontal axis, and the CPKREF option adds reference lines indicating the intersections of the distribution reference line and the specification limits.

Output 10.4.1: Normal Q-Q Plot With C_pk Scaling

Using this display, you can estimate CPU and CPL directly from the horizontal axis as 0.55 and 0.60, respectively (the negative sign for -0.60 is ignored). The minimum of these values (0.55) is an estimate of C_pk. Note that this estimate agrees with the numerically obtained estimate for C_pk that is displayed on the plot with the INSET statement.

See Rodriguez (1992) for further discussion concerning the use of Q-Q plots in process capability analysis.

Chapter Contents
Previous
Next
Top