The CORR Procedure

Example 3: Computing Cronbach's Coefficient Alpha

Procedure features:

PROC CORR statement options:

	ALPHA
	NOCORR
	NOMISS

This example

computes Cronbach's coefficient alpha for a multiple-item mixed-rating scale
suppresses Pearson correlation statistics
excludes observations with missing values using listwise deletion.

This example does not examine the correlation matrix but assumes that all items are positively correlated. Normally, you want to examine the correlation and covariance matrices to make sure that all variables are positively correlated. Positive correlation is needed because items measure a common entity. You exclude negatively correlated items from the analysis because they do not measure the same construct.

Program

options nodate pageno=1 linesize=80 pagesize=60;

data psychdat;
   input Age Anxiety Depression Sleep Sex Life WeightChange @@;
   label age             = 'age in years'
         anxiety         = 'anxiety level'
         depression      = 'depression level'
         sleep           = 'normal sleep (1=y 2=n)'
         sex             = 'sexual (1=n 2=y)'
         life            = 'suicidal (1=n 2=y)'
         weightchange    = 'recent weight change';
    datalines;
39  2   2   2   2   2  4.9 41  2   2   2   2   2  2.2
42  3   3   .   2   2  4.0 30  2   2   2   2   2 -2.6
35  2   1   1   2   1 -0.3 44  .   1   2   1   1  0.9
31  2   2   .   2   2 -1.5 39  3   2   2   2   1  3.5
35  3   2   2   2   2 -1.2 33  2   2   2   2   2  0.8
38  2   1   1   1   1 -1.9 31  2   2   2   .   1  5.5
40  3   2   2   2   1  2.7 44  2   2   2   2   2  4.4
43  3   2   2   2   2  3.2 32  1   1   1   2   1 -1.5
32  1   2   2   .   1 -1.9 43  4   3   2   2   2  8.3
46  3   2   2   2   2  3.6 30  2   2   2   2   1  1.4
34  3   3   .   2   2   .  37  3   2   2   2   1   .
35  2   1   2   2   1 -1.0 45  2   2   2   2   2  6.5
35  2   2   2   2   1 -2.1 31  2   2   2   2   1 -0.4
32  2   2   2   2   1 -1.9 44  2   2   2   2   2  3.7
40  3   3   2   2   2  4.5 42  3   3   2   2   2  4.2
;

proc corr data=psychdat alpha nocorr nomiss;

   title1 'Mental Stability Scale for Female Psychiatric Patients';
run;

Output

The correlation report includes descriptive statistics and Cronbach's coefficient alpha, the correlation between the variable and the total of the remaining variables, and Cronbach's coefficient alpha using the remaining variables for both the raw variables and the standardized variables. These calculations use the 23 observations without missing values.
Because the variances of some variables vary widely, you use the standardized scores to estimate reliability. The overall standardized alpha of .85 is an acceptable reliability coefficient. This is greater than Nunnally's suggested value of .70.
The standardized alpha provides information on how each item reflects the reliability of the scale. Notice that the standardized alpha decreases after removing Depression from the construct. Therefore, this variable appears strongly correlated with other items in the scale. The standardized alpha increases slightly after removing Sex from the construct. Thus, removing this variable from the scale makes the construct more reliable.

Chapter Contents
Previous
Next
Top of Page