Chapter Contents

Previous

Next

Example 1.6: Multiple Projects

Often a project is divided into several subprojects, each of which is then broken into activities with precedence constraints. For reporting or accounting purposes, it may be essential to group activities or to aggregate the information pertaining to activities in a given group. Sometimes, totally different projects use a common pool of resources and you may want to schedule all the projects using the common pool; you may want to vary the priority with which the resources are allotted to the activities on the basis of the projects to which they belong. Often, you have several projects that are essentially the same, with only a few minor differences; these projects may also share a common pool of resources. In such cases, you may want to have a project template listing all the activities and their precedence relationships; for each specific project you can copy the template, make any modifications that are necessary for the given scenario, and determine the project schedule accordingly.

This example illustrates some of these possibilities for a multiproject scenario. The project is first scheduled using PROC CPM, and then the PM procedure is used with the same input data set to illustrate the project displayed in the PM Window.

Suppose that the company is working on two books simultaneously. The editor and artist must now allocate their time between the two books. The following program uses the template data set book to create Activity data sets book1 and book2 corresponding to the publication of each book. Any modifications to the generic project data can be made in the DATA step or by using PROC PM. In this example, the duration for the first activity, `Preliminary Edit', is changed to two weeks for the second book. The two Activity data sets book1 and book2 are also displayed in Output 1.6.2.

   data book1;
      length act $6. succ $6.;
      set book;
      subproj = "Book 1";
      act = "B1"||task;
      if succ ^= " " then succ = "B1"||succ;
      run;

   title 'Publishing Book 1';
   proc print data=book1;
      var subproj task act succ id dur editor artist;
      run;

   data book2;
      length act $6. succ $6.;
      set book;
      subproj = "Book 2";
      act  = "B2"||task;
      if act = "B2PEDT" then dur = 2;
      if succ ^= " "    then succ = "B2"||succ;
      run;

   title 'Publishing Book 2';
   proc print data=book2;
      var subproj task act succ id dur editor artist;
      run;

   data books;
      set book1 book2;
      if subproj = "Book 1" then priority = 1;
      else                       priority = 2;
      run;

   title 'Publishing Books 1 and 2';
   proc print data=books;
      var subproj priority task act succ id dur editor artist;
      run;

   data resource;
      input avdate date7. editor artist;
      format avdate date7.;
      datalines;
   1jan99   1   1
   ;

   title 'Resources Available';
   proc print data=resource;
      run;

   proc cpm data=books resin=resource
            out=bookschd resout=booksout
            date='1jan99'd interval=week
            addact;
      act      act;
      dur      dur;
      succ     succ;
      resource editor artist / per=avdate avp rcp
                               rule=actprty actprty=priority
                               delayanalysis;
      id       id task;
      project  subproj;
      run;

Note: The entire project finishes on April 1, 1999; resource constraints have delayed project completion by four weeks. The variable R_DELAY in the Schedule data set bookschd indicates the amount of delay in weeks caused by resource constraints. The value of R_DELAY does not include any delay in the activity that is caused by a resource delay in one of its predecessors. See Example 2.15 in Chapter 2, "The CPM Procedure" for more details about the R_DELAY variable.

The output data sets bookschd and booksout can be used to produce graphical reports of the schedule and the resource usage. In particular, the Schedule data set can be used to produce a zoned, time-scaled network diagram as shown in Output 1.6.5. The program used to produce the network diagram is shown in the following code. In this example, only the leaf tasks (those without any subtasks) are used to draw the network diagram. Further, the activities are aligned according to the resource-constrained start times and grouped according to the subproject.

   goptions hpos=98 vpos=60;
   pattern1 v=e c=green;
   pattern2 v=e c=red;
   title c=black f=swiss h=4 'Schedule for Project Books';
   proc netdraw data=bookschd(where=(proj_dur=.) graphics;
      actnet / act=task succ=succ font=swiss
               id=(task) nodefid nolabel
               xbetween=8 htext=3 pcompress
               zone=subproj zonepat zonespace
               align=s_start separatearcs;
      label subproj = 'Subproject';
      run;

   proc pm data=books resin=resource
           out=pmsched resout=pmrout
           date='1jan99'd interval=week;
      act      act;
      dur      dur;
      succ     succ;
      resource editor artist / per=avdate
                               avp rcp
                               rule=actprty
                               actprty=priority
                               delayanalysis;
      id       id task;
      project  subproj;
      run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.