Chapter Contents

Previous

Next

Example 16.2: Multipliers for a Third-Order System

This example shows how to fit and simulate a single equation dynamic model with third-order lags. It then shows how to convert the third-order equation into a three equation system with only first-order lags, so that the SIMLIN procedure can compute multipliers. (See the section "Multipliers for Higher Order Lags" earlier in this chapter for more information.)

The input data set TEST is created from simulated data. A partial listing of the data set TEST produced by PROC PRINT is shown in Output 16.2.1.

   title1 'Simulate Equation with Third-Order Lags';
   title2 'Listing of Simulated Input Data';
   proc print data=test(obs=10);
   run;

   title2 'Estimated Parameters';
   proc reg data=test outest=a;
      model y=ylag3 x;
   run;
   
   title2 'Listing of OUTEST= Data Set';
   proc print data=a;
   run;

Output 16.2.2 shows the printed output produced by the REG procedure, and Output 16.2.3 displays the OUTEST= data set A produced.

   title2 'Simulation of Equation';
   proc simlin est=a data=test nored;
      endogenous y;
      exogenous  x;
      lagged ylag3 y 3;
      id n;
      output out=out1 predicted=yhat residual=yresid;
   run;

The printed output from the SIMLIN procedure is shown in Output 16.2.4.

   title2 'Plots of Simulation Results';
   symbol1 i=none v=star;
   symbol2 i=join v=circle;
   proc gplot data=out1;
      plot yhat*n=1 y*n=2 / overlay;
   run;

   data test2;
      set test;
      ylag1x=ylag1;
      ylag2x=ylag2;
   run;
   
   title2 'Estimation of parameters and definition of identities';
   proc syslin data=test2 outest=b;
      endogenous y ylag1x ylag2x;
      model y=ylag3 x;
      identity ylag1x=ylag1;
      identity ylag2x=ylag2;
   run;
   
   title2 'Listing of OUTEST= data set from PROC SYSLIN';
   proc print data=b;
   run;

   title2 'Simulation of transformed first-order equation system';
   
   proc simlin est=b data=test2 total interim=2;
      endogenous y ylag1x ylag2x;
      exogenous  x;
      lagged  ylag1 y 1  ylag2 ylag1x 1  ylag3 ylag2x 1;
      id n;
      output out=out2 predicted=yhat residual=yresid;
   run;

Output 16.2.7 shows the interim 2 and total multipliers printed by the SIMLIN procedure.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.