The PMENU Procedure

Example 1: Building a Menu Bar for an FSEDIT Application

Procedure features:

PROC PMENU statement option:

CATALOG=

ITEM statement options:

	MENU=
	SELECTION=
	SUBMENU=

MENU statement

SELECTION statement

SUBMENU statement

This example creates a menu bar that can be used in an FSEDIT application to replace the default menu bar. The selections available on these pull-down menus do not enable end users to delete or duplicate observations.

Program

libname proclib 'SAS-data-library';

proc pmenu catalog=proclib.menucat;

   menu project;

      item 'File' menu=f;
      item 'Edit' submenu=editmnu;
      item 'Scroll' menu=s;
      item 'Help' menu=h;

      menu f;
         item 'Goback' selection=g;
         item 'Save';
         selection g 'end';

      submenu editmnu sashelp.core.edit;

      menu s;
         item 'Next Obs' selection=n;
         item 'Prev Obs' selection=p;
         item 'Top';
         item 'Bottom';
         selection n 'forward';
         selection p 'backward';

      menu h;
         item 'Keys';
         item 'About this application' selection=hlp;
         selection hlp 'sethelp user.menucat.staffhlp.help;help';
quit;

Associating a Menu Bar with an FSEDIT Session
The following SETPMENU command associates the customized menu bar with the FSEDIT window.

setpmenu proclib.menucat.project.pmenu;pmenu on

You can also specify the menu bar on the command line in the FSEDIT session or with a CALL EXECCMD in Screen Control Language.

See Associating a Menu Bar with an FSEDIT Session for other methods of associating the customized menu bar with the FSEDIT window.

[IMAGE]

Chapter Contents
Previous
Next
Top of Page