Chapter Contents
Previous
Next
The GANNO Procedure

Example 1: Scaling Data-Dependent Output

Procedure features:
PROC GANNO statement options:
ANNOTATE=
DATASYS
Sample library member: GR12N01

[IMAGE]

This example uses an Annotate data set to scale data-dependent output with the DATASYS option and create a vertical bar chart of sales for each of six sites. The values that determine the height of each bar range from 137 to 999. The range of values is so large that the GANNO procedure cannot fit all of the bars in the output area without scaling the output. This program uses the DATASYS option to scale the data values so that the bars fit in the graphics output area.
 Note about code
goptions reset=global gunit=pct cback=white
         colors=(black blue green red);
 Note about code
data wrldtotl;
   length sitename $ 10;
   input sitename $ 1-10 mean 12-15;
   datalines;
Paris      999
Munich     571
Tokyo      137
London     273
Frankfurt  546
New York   991
;
run;
 Note about code
data wrldanno;
   length function color $ 8 text $ 20;
   retain line 0 xsys ysys '2' hsys '3' x 8;
   set wrldtotl end=end;
 Note about code
   function='move'; x=x+8; y=20; output;
   function='bar'; y=y+(mean); x=x+9;
      style='empty'; color='red'; output;
 Note about code
   function='label'; y=0; x=x-4; size=3.5;
      position='E'; style='swiss';
      color='blue'; text=sitename; output;
 Note about code
   function='move'; y=y+(mean)-3; output;
   function='label'; x=x-1; text=left(put(mean,3.));
      position='5'; style='swiss'; size=3; output;
 Note about code
   if end then do;
      function='move'; x=10; y=20; output;
      function='draw'; x=90; y=20; line=1;
         size=.5; color='blue'; output;
      function='label'; x=50; y=95; text='Projected Sales';
         xsys='3'; ysys='3'; position='5'; style='swissb';
         size=5; color=' '; output;
         x=92; y=5; size=3; style='swiss'; text='GR12N01 '; output;
      function='frame'; color='blue'; when='b';
         style='empty'; output;
   end;
run;
 Note about code
proc ganno annotate=wrldanno
   datasys;
run;
quit;


Chapter Contents
Previous
Next
Top of Page

Copyright 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.