Accessing SAS Data Files

Using Version 8 to Access Data Files from Earlier Releases without Converting

A Version 8 SAS session can read and update a Version 6 data file or a Version 7 data file without converting the file as long as the features included in the data file are supported by the file format's version. That is, you cannot use Version 8 features for a Version 6 data file.

In general, you can use Version 8 to manipulate Version 6 data files, using the V6 compatibility engine as long as needed. However, you will not be able to maximize the potential of Version 8 until you convert Version 6 data files to Version 8 format.

Using Version 6 to Access Version 8 Data Files

Version 6 cannot access a Version 8 data file due to differences in the file format, except with SAS/SHARE or SAS/CONNECT software.

Converting Version 6 Data Files to Version 8 Format

Even though you can use Version 8 with Version 6 data files, in order to use Version 8 features such as long variable names, integrity constraints, and generation data sets, you must convert existing data to Version 8 format.

To convert a Version 6 data file to Version 8 format, you can use one of the following methods:

use the V6 compatibility engine and the COPY procedure. In the following example, the first LIBNAME statement specifies the V6 compatibility engine and the libref OLD, which points to the library containing the Version 6 data files. The second LIBNAME statement specifies the V8 engine and the libref NEW, which points to the new library to which the data will be copied. PROC COPY reads the data files identified by the IN= option with the V6 engine and writes them to the new library identified in the OUT= option with the V8 engine. Note that the engine names are specified in the LIBNAME statements for clarity; specifying the engine name is optional.
```
libname old v6 "v6-SAS-data-library";
libname new v8 "v8-SAS-data-library";

proc copy in=old out=new memtype=data;
run;
```
use the V6 compatibility engine and a DATA step.
This technique works well if you want to convert only one or two data files:
```
libname old v6 "v6-SAS-data-library";
libname new v8 "v8-SAS-data-library";

data new.data;
   set old.data;
run;
```
use the CPORT and CIMPORT transport procedures. The following program uses PROC CPORT to create a transport file from the Release 6.12 data file V6LIB.MYDATA:
```
   /* Release 6.12 SAS program */

libname old "v6-SAS-data-library";

proc cport cat=old.mydat file='myxpt.xpt';
run;
```
The next program then uses PROC CIMPORT to convert the transport file to the Version 8 data file NEW.MYDAT:
```
   /* Version 8 SAS program */

libname new "v8-SAS-data-library";

proc cimport cat=new.mydat file='myxpt.xpt';
run;
```
Note: Depending on your operating environment, PROC CPORT and PROC CIMPORT may require different syntax. See the SAS documentation for your operating environment.

Creating Version 6 Data Files in Version 8

You may need to create a Version 6 data file in a Version 8 session, for example, if you are sharing data with a Version 6 application. To do so, you use the V6 compatibility engine. For example, the following statements use the V6 engine to create a SAS data file named QTR1. The raw data is read from the external file associated with the fileref MYFILE:

libname newdata v6 "SAS-data-library";

filename myfile "external-file";

data newdata.qtr1;
   infile myfile;
   input saledata amount;
run;

You may also need to create a Version 6 data file from a Version 8 data file. However, because the Version 8 file could contain features like long variable names that are not compatible with Version 6, you would need to remove Version 8 features. In Version 8, the COPY procedure can automatically truncate long variable names if you specify the VALIDVARNAME=V6 system option.

For example, assume that a Version 8 SAS data file named V8LIB.EMPLOYEE contains the variables LASTNAME, FIRSTNAME, and EMPLOYEEID. By issuing the following PROC COPY with the VALIDVARNAME=V6 system option, the resulting Version 6 SAS data file V6LIB.EMPLOYEE contains the variables LASTNAME, FIRSTNAM, and EMPLOYEE:

libname v8lib "v8-SAS-data-library";

libname v6lib "v6-SAS-data-library";

options validvarname=v6;

proc copy in=v8lib out=v6lib;
   select=employee;
run;

Chapter Contents
Previous
Next
Top of Page